Cooking with CQL Qs&As – Session 44

Thursday, May 28, 2020

## Measure Logic In CQL

**Q:** The Troponin Continuous Variable measure is a pathology-driven quality measure under development that relates to critical value reporting and is seeking the time interval in minutes from the time the results for troponin tests are determined and when the laboratory communicates the critical troponin levels to the responsible provider using the electronic health record (EHR) as the source of the data. The measure observation evaluates only the first troponin test followed by a communication (e.g., email, fax) during the encounter. The communication should be completed after the test and should be related to the test for which it is attributed. The issue is in trying to create the logic to relate the communication about a specific test when there are multiple troponin tests during an encounter. As an example, during an encounter we have two troponin tests and one communication:

* The first troponin test result date time: 2/12/2019 1100
* The second troponin test result date time: 2/12/2019 1205
* The first communication sent date time: 2/12/2019 1305

The measure should be comparing the communication to test result to which it corresponds. The current logic relates the communication to the first troponin test in the example. How can one address a scenario in which there are multiple toponin tests and related each communication to its respective test result?

**A:** Using Quality Data Model (QDM) version 5.5, there are several approaches to consider. The approach depends on the availability of information about the relationship between the communication and the troponin lab test id and whether there is information in the EHR that can link the communication with the lab test.

Expression 1:

The first expression is a multi-source query that says “for every encounter, for every troponin test performed, and for every communication performed, only consider the tests that were performed in the relevant period. The communication should be related to the id.”

|  |  |  |
| --- | --- | --- |
| define function "Minutes between results and communication by id"(Encounter "Encounter, Performed"): | | |
|  | Min( |
|  | from |
|  | ["Laboratory Test, Performed": "Cardiac Troponin"] T, |
|  | ["Communication, Performed": "Lab Communications"] C |
|  | where T.resultDatetime during Encounter.relevantPeriod |
|  | and C.sentDatetime during Encounter.relevantPeriod |
|  | and C.relatedTo includes T.id |
|  | return minutes between T.resultDatetime and C.sentDatetime |
|  | ) |

Expression 2:

The second approach is performed based on timing. The second expression says, “for every laboratory test during this encounter, return the minutes between the result date time and the dateTime the communication is sent.” Using this expression for every laboratory test, it will look for the first communication after that laboratory test. It will return the duration in minutes between availability of the test result and the time the communication is sent so you will get the length of time for every test before a communication came back.

|  |  |
| --- | --- |
| define function "Minutes between results and communication by timing"(Encounter "Encounter, Performed"): | |
|  | Min( |
|  | ["Laboratory Test, Performed": "Cardiac Troponin"] T |
|  | let |
|  | Communication: First( |
|  | ["Communication, Performed": "Lab Communications"] C |
|  | where C.sentDatetime during Encounter.relevantPeriod |
|  | and C.sentDatetime after T.resultDatetime |
|  | sort by sentDatetime |
|  | ) |
|  | return minutes between T.resultDatetime and Communication.sentDatetime |
|  | ) |

Expression 3:

The third expression returns the minutes between communications for the first test and a second test if there are no relatedTo elements in the communications or the relatedTo includes the id. If the EHR is able to provide information whether the communication is relatedTo a specific troponin test, then it will come back as the first and only communication. However, if the EHR is not able to provide the relationship between the communication and the test result, then it will find the first ‘sent’ time of a communication during the encounter that came after the result retrieved.

|  |  |
| --- | --- |
| define function "Minutes between results and communication by id or timing"(Encounter "Encounter, Performed"): | |
|  | Min( |
|  | ["Laboratory Test, Performed": "Cardiac Troponin"] T |
|  | let |
|  | Communication: First( |
|  | ["Communication, Performed": "Lab Communications"] C |
|  | where C.sentDatetime during Encounter.relevantPeriod |
|  | and C.sentDatetime after T.resultDatetime |
|  | and (not exists (C.relatedTo) or C.relatedTo includes T.id) |
|  | sort by sentDatetime |
|  | ) |
|  | return minutes between T.resultDatetime and Communication.sentDatetime |
|  | ) |

**Q:** The Troponin Continuous Variable measure expression provided is looking for minutes between results and communication by id or timing. The expression related to timing makes sense, but the highlighted line says “not exists” so would not that untie the id?

|  |  |
| --- | --- |
| define function "Minutes between results and communication by id or timing"(Encounter "Encounter, Performed"): | |
|  | Min( |
|  | ["Laboratory Test, Performed": "Cardiac Troponin"] T |
|  | let |
|  | Communication: First( |
|  | ["Communication, Performed": "Lab Communications"] C |
|  | where C.sentDatetime during Encounter.relevantPeriod |
|  | and C.sentDatetime after T.resultDatetime |
|  | and (not exists (C.relatedTo) or C.relatedTo includes T.id) |
|  | sort by sentDatetime |
|  | ) |
|  | return minutes between T.resultDatetime and Communication.sentDatetime |
|  | ) |

**A:** The communication includes a relatedTo element, that is a list of strings so the communication is potentially related to multiple items. What this expression is saying is “if there is no relatedTo, then this expression is true.” We would not want to say C.relatedTo includes T.id because if relatedTo is empty, the statement would be false and this component of the expression would not be applied. If we have relatedTo, we should use it, but if we do not have relatedTo, then fall back to timing. The "not exists" (C.relatedTo) component is true if there are no relatedTo T.id elements present, in which case, we rely upon just the timing relationship to link the communication to the appropriate troponin test. If the electronic health record (EHR) is not capturing the explicit link between the order and the communication or does not have the information available, then we are falling back to timing in this approach because the function we’re defining in the example is looking for the minutes between results and communications by id or timing. By having (not exists (C.relatedTo) or C.relatedTo includes T.id) entirely in parenthesis, the entire statement in the parenthesis has to be true.